***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar. 27, 2026                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5944S6V-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u TC=3m
Rg     g1    g2    1.822
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=180  VTO=4.5  LEVEL=3  VMAX=5e4 NFS=9.55e11  GAMMA=1.4)
Rd     d1    d2   3.488e-3    TC=2.700e-3,15u
Dbd     s2    d2    Dbt
.MODEL Dbt   D   (IS=1.198e-12 N=1.010  RS=4e-8  EG=1.15  TT=20n  IKF=1.884e1  TIKF=-3.000e-3
+                 BV=44  TBV1=4.235e-4 TBV2=-2.530e-7  CJO=1.383e-9  M=1.971  VJ=3.184e1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.198e-12 N=1.010  RS=4e-8  EG=1.15  TT=20n  IKF=1.884e1  TIKF=-3.000e-3)
Rdiode  d1  21    1.100e-2 TC=4.000e-3,-2.000e-5
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   6.049e-10
.MODEL     DGD    D(CJO=6.049e-10   M=1.578   VJ=5.163)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.123e-9
.ENDS PJQ5944S6V-AU
*$
